Início / Projetos Arduino / Projetos Squids / Básico / Projeto 40 - Sensor de temperatura e umidade DHT11 com display LCD

---

Projeto 40 - Sensor de temperatura e umidade DHT11 com display LCD

Angelo Luis Ferreira | 01/06/2018 Acessos: 40.176

Objetivo

Neste projeto vamos demonstrar o uso de um LCD como mostrador de temperatura e umidade obtidas através do sensor DHT11. Também mostraremos neste projeto como incluir bibliotecas no IDE do Arduino.

Sensor DHT11 - O DHT11 é um sensor básico de baixo custo utilizado para a medição de temperatura e umidade do ar ambiente através de um termistor e um sensor capacitivo. Existem várias versões diferentes do DHT11 com a mesma aparência e número de pinos. Portanto é importante verificar o data sheet do componente para obter suas características principais. No nosso projeto as características estão descritas na tabela de componentes.

Aplicação

Para fins didáticos e projetos onde é necessária a medição de temperatura e/ou umidade do ambiente.

Componentes necessários

Referência	Componente	Quantidade	Imagem	Observação
Protoboard	Protoboard 830 pontos	1		No mínimo utilizar protoboard com 830 pontos
Jumpers	Kit cabos ligação macho / macho	1
Display LCD	Display LCD 16X2 com pinos	1		LCD que utilize o controlador HD44780 (veja na descrição ou datasheet do componente) O display poderá ser de qualquer cor (fundo verde, azul ou vermelho)
Potenciômetro	Potenciômetro 1OK	1		O valor do potenciômetro aumenta quando giramos o eixo do componente na direção do polo negativo para o polo positivo. Obs.: Se não possuir potenciômetro de 10KΩ você poderá utilizar um de outro valor, de 1kΩ até 100kΩ.
Sensor de Temperatura e Umidade DHT11	Sensor de Temperatura DHT 11	1		Características do DHT11 utilizado neste exemplo: Tensão de alimentação: 3V a 5V Umidade relativa: 20% a 90% (precisão de 5%) Temperatura: 0 a 50 ºC (precisão de 2%) Intervalo entre medições: mínimo 2s Corrente de utilização: 2,5mA datasheet
Arduino UNO	Arduino UNO	1		Você poderá utilizar uma placa Arduino UNO original ou similar

Montagem do Circuito

Conecte os componentes no Protoboard como mostra a figura abaixo. Verifique cuidadosamente os cabos de ligação antes de ligar seu Arduino. Lembre-se que o Arduino deve estar totalmente desconectado da força enquanto você monta o circuito.

Atenção

1. Neste projeto vamos utilizar um display LCD 16x2 com controlador HD44780, que se adapta aos mais diversos projetos com vários modelos de placas e microcontroladores. Este display possui 16 colunas por 2 linhas com backlight (luz de fundo) verde, azul ou vermelha e tem 16 pinos para a conexão. Atenção: Utilize um display LCD com os pinos soldados.

2. Preste muita atenção na montagem do dsiplay LCD. Observe que utilizamos os 6 primeiros pinos do LCD, pulamos os 4 próximos e então utilizamos mais 6 pinos. Veja a tabela abaixo:

3. Cuidado para não ligar o sensor de temperatura invertido. Ele deve ficar com a face com quadriculada virada para frente e conectado da seguinte forma:

Veja como deve ser a montagem no Arduino:

3.1. O pino 1 deverá estar conectado no polo positivo Vcc - tensão de contínua contínua de 3.3V a 5V.

3.2. O pino 2 deverá estar conectado em uma porta analógica do Arduino. No nosso projeto utilizamos a porta analógica A1.

3.2.1. ATENÇÃO: Para evitar flutuações e garantir que o sinal seja lido corretamente é recomendável acrescentar um resistor "pullup" de 4,7KΩ a 10KΩ.

3.2.2. Veja abaixo como deve ser a montagem do resistor "pullup":

3.3. Pino 3 não deverá estar conectado (NC - não conectado);

3.4. Pino 4 deverá estar conectado ao polo negativo GND - tensão 0V)

3.4. Veja abaixo a montagem do sensor sem o resistor pull up.

ATENÇÃO:  Se ocorrer leitura "zero" ou variações bruscas de leitura, será necessário a inclusão do resistor pull up no circuito, como mostramos acima.

4. Observe que nesse projeto o potenciômetro foi montado como um divisor de tensão, onde utilizamos os 3 terminais do componente:

Obs.: Ao girar o eixo do potenciômetro, o valor da tensão deverá aumentar do negativo para o positivo, ou seja, se a tensão do circuito for 5V, o potenciômetro irá variar de 0 a 5V.

4.1. No nosso exemplo, girando-se o eixo do potenciômetro no sentido horário, aumentamos a tensão na entrada do pino 3 do display e diminuímos o contraste dos caracteres com o back light (luz de fundo) até que não é mais possível visualizá-los. Fazendo o contrário, ou seja, diminuindo a tensão até o zero, teremos um contraste máximo entre os caracteres e a luz de fundo.

5. A montagem do nosso projeto foi realizada em um protoboard com linhas de alimentação não contínuas, onde acrescentamos jampers para a ligação. Verifique se o seu protoboard possui linhas de alimentação contínuas ou separadas - saiba mais em protoboard

ATENÇÃO:  Se ocorrer leitura "zero" ou variações bruscas de leitura, será necessário a inclusão do resistor pull up no circuito, como mostramos acima.

Incluindo bibliotecas no IDE do Arduino

Neste projeto vamos mostrar como adicionar uma biblioteca no IDE do Arduino. Uma das grandes vantagens das placas Arduino é a diversidade de bibliotecas disponíveis que podem ser utilizadas em seus programas. Estas bibliotecas podem ser criadas para a linguagem "C" ou especificamente para o Arduino, reduzindo drasticamente o tempo gasto com programação.

Download dos arquivos da biblioteca do sensor DHT11

Para trabalharmos de forma mais fácil com o sensor DHT, podemos baixar a biblioteca DHTlib que foi desenvolvida para os sensores DHT11, DHT22, DHT33 e DHT44:

 DOWNLOAD - DHTlib.zip

Para saber detalhes desta biblioteca clique aqui.

Instalando a biblioteca pelo IDE do Arduino

Após fazer o download do arquivo DHPlib.zip com todos os arquivos da biblioteca compactados no formato zip, abra o IDE do Arduino. No menu superior, clique em Scketch -> Incluir biblioteca -> Adicionar biblioteca.ZIP para enviar o arquivo.

Selecione o arquivo que você baixou e clique no botão Abrir.

Desta forma, a nova biblioteca foi instalada. Para utilizá-lo basta ir em Sketch -> Incluir Biblioteca e selecionar a biblioteca DHTlib.

Observe que o IDE adicionou no início do seu código a linha #include que é o comando para você incluir a biblioteca para utilização de qualquer sensor DHT.

Ligando o display LCD

1. Para visualizar o display funcionando, digite o código abaixo no ambiente de desenvolvimento IDE do Arduino. Faça a verificação e o upload:

/*******************************************************************************
*
*          Testando o Display LC 16 X 2
*            http://squids.com.br/arduino
*
*******************************************************************************/
//Carrega a biblioteca LiquidCrystal
#include <LiquidCrystal.h>

//Define os pinos que serão utilizados para ligação ao display
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

void setup() {
//Define LCD 16 colunas por 2 linhas
lcd.begin(16, 2);

//Posiciona o cursor na coluna 0, linha 0;
lcd.setCursor(0,0);
//Envia o texto entre aspas para o LCD
lcd.print("Ola, meu nome e:");

//Posiciona o cursor na coluna 1, linha 1;
lcd.setCursor(1,1);
//Envia o texto entre aspas para o LCD
lcd.print("Squids Arduino");
}

void loop() {

} 

2. Se o display acender e mostrar os caracteres como na figura abaixo, a ligação está correta.

ATENÇÃO: Se o display acender e não mostrar os caracteres provavelmente é em função do contraste. Gire o eixo do potenciômetro no sentido anti-horário para aumentar o contraste. Se mesmo assim o display não mostrar os caracteres, corrija a montagem do circuito e/ou o código.

Comandos do display LCD para a biblioteca LiquidCrystal

No projeto vamos utilizar alguns comandos de controle do display LCD através da biblioteca LiquidCrystal que já vem embutida na IDE do Arduino. Para conhecer todos os comandos desta biblioteca, acesse o link: Comandos display LCD para biblioteca LiquidCrystal e LiquidCrystal Library (Arduino Reference).

Obs.: Para acessarmos uma biblioteca embutida na IDE do Arduino, assim como, para acessarmos um biblioteca local através de um header file, utilizaremos a diretiva #include.

Código do Projeto (Sketch)

1) Faça o dowload e abra o arquivo projeto40.ino no IDE do Arduino:  DOWNLOAD - projeto40.ino

Ou se preferir, copie e cole o código abaixo no IDE do Arduino:

/*******************************************************************************
*
*    Projeto 40 - Utilizando um sensor de temperatura e umidade DHT11 com LCD 
*            http://squids.com.br/arduino
*
*******************************************************************************/
#include <dht.h> // Inclui a biblioteca no seu código
#include <LiquidCrystal.h>  //Carrega a biblioteca LiquidCrystal nativa na IDE

//Define os pinos que serão utilizados para ligação ao display
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
 
dht DHT; // Cria um objeto da classe dht
uint32_t timer = 0;
 
void setup()
{
  Serial.begin(9600); // Inicializa serial com taxa de transmissão de 9600 bauds
  lcd.begin(16, 2); // Define o display com 16 colunas e 2 linhas
  lcd.clear(); // limpa a tela do display
}
 
void loop() {
  // Executa 1 vez a cada 2 segundos
  if(millis() - timer>= 2000)
  {
 
    DHT.read11(A1); // chama método de leitura da classe dht,
                    // com o pino de transmissão de dados ligado no pino A1
 
    // Exibe na serial o valor de umidade
    Serial.print("Umidade = ");
    Serial.print(DHT.humidity);
    Serial.print(" %  ");
 
    // Exibe na serial o valor da temperatura
    Serial.print("Temperatura = ");
    Serial.print(DHT.temperature); 
    Serial.println(" Celsius  ");

    // Exibe no display LCD o valor da humidade
    lcd.setCursor(0,0); // Define o cursor na posição de início
    lcd.print("Humd. = ");
    lcd.print(DHT.humidity);
    lcd.print("%");

    // Exibe no display LCD o valor da temperatura
    lcd.setCursor(0,1); // Define o cursor na posição de início
    lcd.print("Temp. = ");
    lcd.print(DHT.temperature);
    lcd.write(B11011111); // Imprime o símbolo de grau
    lcd.print("C");

    timer = millis(); // Atualiza a referência
  }
} 

Vídeo

Como o projeto deve funcionar

1. Ao executar o programa, a temperatura atual, em Celsius, e a umidade relativa, em porcentagem, serão exibidas no display LCD e atualizadas a cada 2 segundos.

2. Para visualizar a leitura das temperaturas e umidade relativa registradas, clique no ícone monitor serial, como mostra a figura abaixo:

Explicando o Código do Projeto

1. Primeiro definimos e declaramos as bibliotecas, constantes e variáveis do projeto.

1.1. Através do comando #include incluímos as bibliotecas dht.h e LiquidCrystal.h para serem compiladas junto ao sketch (não utilize ponto e vírgula no final de uma diretiva #include).

1.1.1. A diretiva #include é utilizada para incluir bibliotecas externas em um sketch. Isso dá ao programador acesso a um grande grupo de bibliotecas C padrão (grupos de funções pré definidas) e também bibliotecas específicas para o Arduino.

1.1.2. Como já mencionamos anteriormente, o arquivo da biblioteca dht.h deve ser inserido no IDE do Arduino. Se tiver dúvidas leia o artigo Como incluir uma biblioteca no IDE do Arduino.

1.1.3. A biblioteca LiquidCrystal.h já vem incluída no IDE do Arduino e contém todos os comandos e recursos para controlar um display LCD.

1.2.  Através da instrução LiquidCrystal lcd(12, 11, 5, 4, 3, 2); a biblioteca do LCD faz com que o programa do Arduino saiba que ao dar o comando LiquidCrystal lcd iremos utilizar um display, e faremos a comunicação utilizando os seguintes pinos do Arduino: 12, 11, 5, 4, 3, conforme mostra a tabela abaixo:

1.3. O comando dht DHT instancia o objeto definido pela classe dht inserida na biblioteca dht.h. Isto faz com que possamos utilizar todos os métodos (funções) da biblioteca para uso no programa.

1.4. Observe que utilizamos a variável tipo unit32_t. Veja na tabela abaixo as diferenças nos tipos de constantes e variáveis:

 1.5. Definimos a variável timer tipo uint32_t que recebe o valor zero.

2. Através da estrutura void setup(), definimos:

2.1. A função Serial.begin() serve para dizer ao Arduino que será coletado dados para o computador a partir da porta serial e o cabo USB. O número entre os parênteses significa qual é a taxa de dados que a placa vai se comunicar com o computador. Utilizaremos a taxa padrão de 9600bps (bits-per-second).

2.2. Através da instrução lcd.begin(16,2); a biblioteca do LCD informa ao Arduino que será utilizado um display com 16 colunas e 2 linhas.

2.3. O comando lcd.clear() limpa a tela do display LCD,

3. Através da estrutura void loop(), obtemos:

3.1. Através da expressão condicional if(millis() - timer >= 2000) verificamos se o valor da função millis() sbutraído do valor da variável timer é menor ou igual a 2000ms (2 segundos), sendo que:

3.1.1. A função millis() retorna o número de milissegundos passados desde que a placa Arduino começou a executar o programa atual. Esse número irá sofrer overflow (chegar ao maior número possível e então voltar pra zero), após aproximadamente 50 dias.

3.1.2. A variável timer  tipo uint32_t, recebe inicialmente o valor zero.

3.1.3. Assim, quando a diferença entre a função milis() e zero (valor inicial de timer) for maior que 2.000, a expressão condicional será verdadeira e todos comandos inerentes a ela serão executados. Isto significa que, o programa roda durante 2 segundos sem executar os comandos definidos pela expressão if(millis() - timer >= 2000;  fazendo com que estes comandos somente sejam executados a cada 2 segundos.

Obs.: É importante salientar que a utilização da função millis() como condicional é diferente de utilizamos a função pause() que paralisa totalmente o programa por um determinado período. Leia mais: função millis().

 3.2. Caso a expressão condicional if(millis() - timer >= 2000) seja atendida, os seguintes comandos são realizados:

3.2.1. A expressão DHT.read11(A1); executa o método DHT.read11() da biblioteca dht.h permitindo realizar as leituras do sensor DHT11 que está conectado no pino analógico A1 do Arduino.

3.2.2. É exibido no Monitor Serial o valor da Temperatura em Celsius, através da diretiva DHT.temperatura, que faz parte do método DHT.read(). Para saber detalhes desta biblioteca clique aqui.

3.2.3. Da mesma forma é exibido o valor da Umidade Relativa do ar em porcentagem, através da diretiva DHT.humidity, que também faz parte do método DHT.read(). Para saber detalhes desta biblioteca clique aqui.

3.2.3. Em seguida, será exibido no display LCD o valor da umidade lido pelo comando DHT.humidity, sendo que:

Obs.: Para saber mais detalhes da biblioteca LiquidCrystal, leia: Biblioteca LiquidCrystal - Comandos display LCD

3.2.3.1. Através do comando lcd.setCursor(0,0) definimos a posição do cursor no primeiro caractere da primeira linha do display.

3.2.3.2. Com base na posição do cursor definida acima, é exibido no display LCD o texto "Humid. = ", através do comando lcd.print().

3.2.3.3. É exibido o valor da umidade relativa do ar obtida pela leitura no DHT11 através do comando lcd.print( DHT.humidity);

3.2.3.4. Através do comando lcd.print() é exibida no display LCD a string "%".

3.2.4. Finalmente, é exibido no display o valor da temperatura lido pelo comando DHT.temperature, sendo que:

Obs.: Para saber mais detalhes da biblioteca LiquidCrystal, leia: Biblioteca LiquidCrystal - Comandos display LCD

3.2.4.1. Através do comando lcd.setCursor(0,1) definimos a posição do cursor no primeiro caractere da segunda linha do display.

3.2.4.2. Com base na posição do cursor definida acima, é exibido no display LCD o texto "Temp. = ", através do comando lcd.print().

3.2.4.3. É exibido o valor da temperatura obtida pela leitura no DHT11 através do comando lcd.print( DHT.temperature);

3.2.4.4. Através do comando lcd.write(B11011111) é exibida o símbolo de grau (º):

3.2.4.4.1. Diferentemente de lcd.print(), que imprime uma string no display, a função lcd.write() imprime um caractere.

3.2.4.4.2. Utilizamos um valor binário para definir o nosso caractere (11011111). Em C++, precisamos utilizar o prefixo "B" antes de um número binário, por isso lcd.write(B11011111) . Veja a tabela abaixo:

Obs.: Leia a referência para usos de constantes com base binário, octal ou hexadecimal  - Constantes Inteiras

3.2.4.4.3. Se você converter o valor binário 11011111 para decimal e hexadecimal encontrará os valores 223 (decimal) e DF (hexadecimal). Assim, você poderia escrever lcd.write(B11011111) como lcd.write(223) ou lcd.write(0xDF) que o símbolo de grau seria exibido de qualquer forma. Obs.: Teste as conversões na Calculadora para Converter número Decimal para Binário, Octal e Hexadecimal.

3.2.4.4.4. O valor do caractere utilizado foi obtido na tabela de caracteres para display LCD com controlador HD44780 abaixo. Usamos o prefixo 1101 (linha horizontal) com o final xxxx1111 (linha vertical) e obtemos o valor binário 11011111. (Nota do Autor: Lembre-se, um caractere tem 1byte, ou seja, 8 bits).

ATENÇÃO: Esta tabela pode variar para outros tipos de displays.

3.2.4.5. Através do comando lcd.print() é exibida no display LCD a string "C".

 3.2.5. Finalmente, a expressão timer = millis(); faz com que a variável timer receba agora o valor de millis() após 2000ms, reiniciando a contagem para a próxima exibição dos valores que atualizará as leituras do sensor de temperatura DHT11.

Desafios

Com base neste projeto, resolva o seguinte desafio:  Desafio 21

Comentários